Docs / Language Manual / Function

You are currently looking at the v8.0.0 docs (Reason v3.6 syntax edition). You can find the latest manual page here.

Function

Cheat sheet for the full function syntax at the end.

Functions are declared with an arrow and return an expression.

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let greet = (name) => "Hello " ++ name;

This declares a function and assigns to it the name greet, which you can call like so:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
greet("world!"); // "Hello world!"

Multi-arguments functions have arguments separated by comma:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let add = (x, y, z) => x + y + z;
add(1, 2, 3); // 6

For longer functions, you'd surround the body with a block:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let greetMore = (name) => {
  let part1 = "Hello";
  part1 ++ " " ++ name;
};

If your function has no argument, just write let greetMore = () => {...}.

Labeled Arguments

Multi-arguments functions, especially those whose arguments are of the same type, can be confusing to call.

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let addCoordinates = (x, y) => {
  // use x and y here
};
// ...
addCoordinates(5, 6); // which is x, which is y?

You can attach labels to an argument by prefixing the name with the ~ symbol:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let addCoordinates = (~x, ~y) => {
  // use x and y here
};
// ...
addCoordinates(~x=5, ~y=6);

You can provide the arguments in any order:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
addCoordinates(~y=6, ~x=5);

The ~x part in the declaration means the function accepts an argument labeled x and can refer to it in the function body by the same name. You can also refer to the arguments inside the function body by a different name for conciseness:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let drawCircle = (~radius as r, ~color as c) => {
  setColor(c);
  startAt(r, r);
  // ...
};

drawCircle(~radius=10, ~color="red");

As a matter of fact, (~radius) is just a shorthand for (~radius as radius).

Here's the syntax for typing the arguments:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let drawCircle = (~radius as r: int, ~color as c: string) => {
  // code here
};

Optional Labeled Arguments

Labeled function arguments can be made optional during declaration. You can then omit them when calling the function.

Reason (Old Syntax)ML (Older Syntax)JS Output
 
// radius can be omitted
let drawCircle = (~color, ~radius=?, ()) => {
  setColor(color);
  switch (radius) {
  | None => startAt(1, 1)
  | Some(r_) => startAt(r_, r_)
  };
};

When given in this syntax, radius is wrapped in the standard library's option type, defaulting to None. If provided, it'll be wrapped with a Some. So radius's type value is None | Some(int) here.

More on option type here.

Note for the sake of the type system, whenever you have an optional argument, you need to ensure that there's also at least one positional argument (aka non-labeled, non-optional argument) after it. If there's none, provide a dummy unit (aka ()) argument.

Signatures and Type Annotations

Functions with optional labeled arguments can be confusing when it comes to signature and type annotations. Indeed, the type of an optional labeled argument looks different depending on whether you're calling the function, or working inside the function body. Outside the function, a raw value is either passed in (int, for example), or left off entirely. Inside the function, the parameter is always there, but its value is an option (option(int)). This means that the type signature is different, depending on whether you're writing out the function type, or the parameter type annotation. The first being a raw value, and the second being an option.

If we get back to our previous example and both add a signature and type annotations to its argument, we get this:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let drawCircle: (~color: color, ~radius: int=?, unit) => unit =
  (~color: color, ~radius: option(int)=?, ()) => {
    setColor(color);
    switch (radius) {
    | None => startAt(1, 1)
    | Some(r_) => startAt(r_, r_)
    };
  };

The first line is the function's signature, we would define it like that in an interface file (see Signatures). The function's signature describes the types that the outside world interacts with, hence the type int for radius because it indeed expects an int when called.

In the second line, we annotate the arguments to help us remember the types of the arguments when we use them inside the function's body, here indeed radius will be an option(int) inside the function.

So if you happen to struggle when writing the signature of a function with optional labeled arguments, try to remember this!

Explicitly Passed Optional

Sometimes, you might want to forward a value to a function without knowing whether the value is None or Some(a). Naively, you'd do:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let result =
  switch (payloadRadius) {
  | None => drawCircle(~color, ())
  | Some(r) => drawCircle(~color, ~radius=r, ())
  };

This quickly gets tedious. We provide a shortcut:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let result = drawCircle(~color, ~radius=?payloadRadius, ());

This means "I understand radius is optional, and that when I pass it a value it needs to be an int, but I don't know whether the value I'm passing is None or Some(val), so I'll pass you the whole option wrapper".

Optional with Default Value

Optional labeled arguments can also be provided a default value. In this case, they aren't wrapped in an option type.

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let drawCircle = (~radius=1, ~color, ()) => {
  setColor(color);
  startAt(radius, radius);
};

Recursive Functions

ReScript chooses the sane default of preventing a function to be called recursively within itself. To make a function recursive, add the rec keyword after the let:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let rec neverTerminate = () => neverTerminate()

A simple recursive function may look like this:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
// Recursively check every item on the list until one equals the `item`
// argument. If a match is found, return `true`, otherwise return `false`
let rec listHas = (list, item) =>
  switch (list) {
  | [] => false
  | [a, ...rest] => a === item || listHas(rest, item)
  };

Recursively calling a function is bad for performance and the call stack. However, ReScript intelligently compiles tail recursion into a fast JavaScript loop. Try checking the JS output of the above code!

Mutually Recursive Functions

Mutually recursive functions start like a single recursive function using the rec keyword, and then are chained together with and:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let rec callSecond = () => callFirst()
and callFirst = () => callSecond();

Uncurried Function

ReScript's functions are curried by default, which is one of the few performance penalties we pay in the compiled JS output. The compiler does a best-effort job at removing those currying whenever possible. However, in certain edge cases, you might want guaranteed uncurrying. In those cases, put a dot in the function's parameter list:

Reason (Old Syntax)ML (Older Syntax)JS Output
 
let add = (. x, y) => x + y;

add(. 1, 2);

If you write down the uncurried function's type, you'll add a dot there as well.

Note: both the declaration site and the call site need to have the uncurry annotation. That's part of the guarantee/requirement.

This feature seems trivial, but is actually one of our most important features, as a primarily functional language. We encourage you to use it if you'd like to remove any mention of Curry runtime in the JS output.

Tips & Tricks

Cheat sheet for the function syntaxes:

Declaration

Reason (Old Syntax)ML (Older Syntax)
 
// anonymous function
(x, y) => 1;
// bind to a name
let add = (x, y) => 1;

// labeled
let add = (~first as x, ~second as y) => x + y;
// with punning sugar
let add = (~first, ~second) => first + second;

// labeled with default value
let add = (~first as x=1, ~second as y=2) => x + y;
// with punning
let add = (~first=1, ~second=2) => first + second;

// optional
let add = (~first as x=?, ~second as y=?) => switch (x) {...};
// with punning
let add = (~first=?, ~second=?) => switch (first) {...};

With Type Annotation

Reason (Old Syntax)ML (Older Syntax)
 
// anonymous function
(x: int, y: int): int => 1;
// bind to a name
let add = (x: int, y: int): int => 1;

// labeled
let add = (~first as x: int, ~second as y: int) : int => x + y;
// with punning sugar
let add = (~first: int, ~second: int) : int => first + second;

// labeled with default value
let add = (~first as x: int=1, ~second as y: int=2) : int => x + y;
// with punning sugar
let add = (~first: int=1, ~second: int=2) : int => first + second;

// optional
let add = (~first as x: option(int)=?, ~second as y: option(int)=?) : int => switch (x) {...};
// with punning sugar
// note that the caller would pass an `int`, not `option(int)`
// Inside the function, `first` and `second` are `option(int)`.
let add = (~first: option(int)=?, ~second: option(int)=?) : int => switch (first) {...};

Application

Reason (Old Syntax)ML (Older Syntax)
 
add(x, y);

// labeled
add(~first=1, ~second=2);
// with punning sugar
add(~first, ~second);

// application with default value. Same as normal application
add(~first=1, ~second=2);

// explicit optional application
add(~first=?Some(1), ~second=?Some(2));
// with punning
add(~first?, ~second?);

With Type Annotation

Reason (Old Syntax)ML (Older Syntax)
 
// labeled
add(~first=1: int, ~second=2: int);
// with punning sugar
add(~first: int, ~second: int);

// application with default value. Same as normal application
add(~first=1: int, ~second=2: int);

// explicit optional application
add(~first=?Some(1): option(int), ~second=?Some(2): option(int));
// no punning sugar when you want to type annotate

Standalone Type Signature

Reason (Old Syntax)ML (Older Syntax)
 
// first arg type, second arg type, return type
type add = (int, int) => int;

// labeled
type add = (~first: int, ~second: int) => int;

// labeled
type add = (~first: int=?, ~second: int=?, unit) => int;

In Interface Files

To annotate a function from the implementation file (.re) in your interface file (.rei):

Reason (Old Syntax)ML (Older Syntax)
 
let add: (int, int) => int;

The type annotation part is the same as the previous section on With Type Annotation.

Don't confuse let add: myType with type add = myType. When used in .rei interface files, the former exports the binding add while annotating it as type myType. The latter exports the type add, whose value is the type myType.